В b2spice A_D кто силён? Помощи треба.

Есть ряд вопросов по моделям. Последний раз с симуляторами общался больше 10 лет назад, изучать весь мануал нет ни сил, ни желания. Тем более, моделировать по сути надо одну-две схемы, только лампы в них менять. А с моделями их загвоздочка и вышла. Модели есть, но микрокаповские. Не дружат даже через импорт. Методология прописывания разная, не хочется методом тыка вписывать.
Помогите, кто понимает, пожалуйста. Если надо - возмездно.

А на что модели нужны? В тырнете спайсовские практически на что угодно найти можно. Для ламп на next-tube куча моделей, например.

Модели е, но конкретно в этот спайс не лезут. Есть и софтина, которая по сканированым ВАХ-ам формулы отписывает. Но. Система описания чуть отличается. А это надо знать, а не пробовать. Потому и спрашиваю. Может кто из местных поможет на взаимообразной основе. И потом, этот спайс есть в бесплатном варианте, не триальный и не ворованный. Может это смешно, но в последнее время как-то ломает с краденым софтом работать.

Т. е. стандартные PSpice описания она не берёт?

Вот из типовой библиотеки
*$
.SUBCKT 6N28B-V 1 2 3 ; P G C (Triode) 12-Dec-2004
+ PARAMS: MU= 22.45 EX= 1.369 KG1= 458.9 KP= 82.65
+ KVB= 300.0 VCT= 0.00 RGI=1500
+ CCG=3.3P CGP=2P CCP=2.2P
E1 7 0 VALUE=
+{V(1,3)/KP*LN(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID;
C2 2 1 {CGP} ; GRID-PLATE;
C3 1 3 {CCP} ; CATHODE-PLATE;
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

А вот из b2spice от "родной" лампочки
.subckt 12ax7a a g k
*
* calculate contribution to anode current
*
bca ca 0 v=45+v(a,k)+95.43*v(g,k)
*
* reduction at low va
*
bre re 0 v=uramp(v(a,k)/5)-uramp(v(a,k)/5-1)
baa a k i=v(re)*1.147e-6*(uramp(v(ca))^1.5)
*
* grid current
*
bgg g k i=5e-6*(uramp(v(g,k)+0.2)^1.5)
*
* capacitances
*
cgk g k 1.6p
cgp g a 1.7p
cpk a k 0.46p
.ends 12ax7a

p g c - ладно, поменять можно, с ёмкостями тоже просто, но номерные обозначения и формулы - кто к чему - не втыкаюсь. Это знать надо, а не гадать.

ага, почитал сейчас фак на сайте Beige Bag Software
действительно, ряд директив и функций у b2spice и PSpice не совпадают :-(

По сути мне нужно адаптировать под б2 только 6н2п, 6н23п, 6н24п, 6н8с, 6н9с, 6н28б, 6с51н, 6с52н - то, что в запасе есть, чисто винил-корректоры и преды гонять. В б2 есть примитив - готовая анти-RIAA цепочка, тем и удобно - не под кривую подгоняешь параметры, а уже под прямую. И сразу видно, где косяк, на сколько дБ уходит. Из родной библиотеки - только аналог 6н2п подходит, и то весьма приблизительно.
Конечно, потом вживую ещё гонять, через железную антириаа и комп с rmaa, но отработать параметры под конкретные лампочки в симуляторе всяко удобнее, особенно если с распределённой коррекцией работать.
А SRPP - вообще, проще на макете или в симуляторе отработать, чем на бумаге расчитывать. И сам к такому выводу пришёл, и умные профессора, почесав затылок, так же ответили :-)

Всё, разобрался сам.

Тему можно закрыть.

[Сообщение изменено пользователем 23.05.2009 16:17]

Поделитесь опытом, думаю, всем будет интересно. :-)

.subckt 6n28b A G K
be1 7 0 v=v(a,k)/82.65*ln(1+exp(82.65*(1/22.45+(v(g,k)+0)/sqrt(300+v(a,k)*v(a,k)))))
bg1 a k i=2*((uramp(v(7)^1.369)-uramp(v(7)-700))^1.369)/458.9
rcp a k 1g
re1 7 0 1g
c1 g k 3.3p
c2 g a 2p
c3 a k 2.2p
d3 5 k dx
r1 g 5 1500
.model dx d(is=1n rs=1 cjo=10p tt=1n)
.ends

.subckt 6S52N A G K
be1 7 0 v=v(a,k)/230.58*ln(1+exp(230.58*(1/70.32+(v(g,k)+0)/sqrt(300+v(a,k)*v(a,k)))))
bg1 a k i=2*((uramp(v(7)^1.250)-uramp(v(7)-700))^1.250)/188.8
rcp a k 1g
re1 7 0 1g
c1 g k 4.35p
c2 g a 1.9p
c3 a k 1.3p
d3 5 k dx
r1 g 5 1500
.model dx d(is=1n rs=1 cjo=10p tt=1n)
.ends

.subckt 6S51N A G K
be1 7 0 v=v(a,k)/99.63*ln(1+exp(99.63*(1/54.72+(v(g,k)+0)/sqrt(300+v(a,k)*v(a,k)))))
bg1 a k i=2*((uramp(v(7)^1.248)-uramp(v(7)-700))^1.248)/123.5
rcp a k 1g
re1 7 0 1g
c1 g k 4.35p
c2 g a 1.9p
c3 a k 1.3p
d3 5 k dx
r1 g 5 1500
.model dx d(is=1n rs=1 cjo=10p tt=1n)
.ends

Вроде так. Модели с ними работают, по крайней мере.
Нашёл пример перевода из пспайса в бспайс на буржуйском радиофоруме, по аналогии перекатал. Только что там за "700" - так и не понял. Может, это и неверно.

Хреновые модели :-)
В малосигнальных режимах кажут прогноз погоды на позавчера.
Ну их в... проще и быстрее обычным калькулятором сосчитать да смакетировать, чем в кнопки тыкать.